アクションゲーム作成ログ

状況

そろそろゲームを作るべく、まずはAAの表示方法を調べる。
http://hakuhin.hp.infoseek.co.jp/main/as3.htmlhttp://hakuhin.hp.infoseek.co.jp/main/as3/text_field.htmlから、テキスト表示まわりを再確認し、それをBitmapで表示するためにhttp://hakuhin.hp.infoseek.co.jp/main/as3/bitmap.html#BITMAP_04に書かれていることを実行する。
ちなみに、テキストそのままではなくBitmapを使うのは、反転処理が必要になると思われるため。これはAS2の時にやっていたので早く済んだ。


さらにちなみに、http://www.kajisoku.com/archives/0006.htmlを参考にゲームを作る予定。


Box2Dでコリジョンが埋まる問題は、接触前にクリックしてフォーカスを当てれば直った。なので、クリックでスタートするように変更した。

swf

クリックでスタート。左右キーで移動。上キーでジャンプもどき。


コード

もう少し色々試した後に、プレイヤーとかのクラス分けをやる予定。

//mxmlc Main.as
//author Show=O=Healer

package {
	import Box2D.Dynamics.*;
	import Box2D.Collision.*;
	import Box2D.Collision.Shapes.*;
	import Box2D.Common.Math.*;
	import flash.events.Event;
	import flash.display.*;
	import flash.text.TextField;
	//Input
	import flash.ui.Keyboard;
	import flash.events.KeyboardEvent;
	//AA
	import flash.geom.*;

	[SWF(backgroundColor="#ffffff", width="350", height="200")]
	public class Main extends Sprite {
		private var m_world:b2World;
		private var m_physScale:Number = 10;

		static public const GRAVITY:Number = 10.0;

		//Player
		private var m_Player:b2Body;
		private var m_PlayerGraphic:Sprite;

		//弾
		private var m_BulletBd:b2BodyDef;
		private var m_Bullet:Array = new Array;

		//Input
		private var m_InputL:int = 0;
		private var m_InputR:int = 0;
		private var m_InputU:int = 0;
		private var m_InputD:int = 0;
		private var m_InputSpace:int = 0;

		static public const KEY_S:int = 83;

		//Param
		public static const FLOOR_W:Number = 400;
		public static const FLOOR_H:Number = 10;
		public static const FLOOR_Y:Number = 250;

		public static const BLOCK_W:Number = 40;
		public static const BLOCK_H:Number = 20;
		public static const BLOCK_X:Number = 300;

		public static const PLAYER_X:Number = 50;
		public static const PLAYER_Y:Number = 220;
		public static const PLAYER_R:Number = 10;
		public static const PLAYER_V:Number = 10;

		public static const BULLET_X:Number = 50;
		public static const BULLET_Y:Number = 220;
		public static const BULLET_R:Number = 10;
		public static const BULLET_V:Number = 100;

		public function Main() {
			stage.scaleMode = "noScale";
			stage.align = "TL";

			var text:TextField = new TextField();
			text.text = "CLICK TO START!!!";
			text.x = text.y = 100;
			addChild(text);

			stage.addEventListener("click", function(event:Event):void {
				text.visible = false;
				Init();
			});
		}

		//どうも、クリックでフォーカスを当てないとBox2Dがめりこむので、コンストラクタから分離
		private function Init():void {
			{//Init Input
				stage.addEventListener(KeyboardEvent.KEY_DOWN, onKeyDown);
				stage.addEventListener(KeyboardEvent.KEY_UP, onKeyUp);
			}

			{//Init Box2D
				{//Common
					//AABB
					var worldAABB:b2AABB = new b2AABB();
					worldAABB.minVertex.Set(-100.0, -100.0);
					worldAABB.maxVertex.Set(100.0, 100.0);
					//Gravity
					var g:b2Vec2 = new b2Vec2(0.0, GRAVITY);
					//World
					m_world = new b2World(worldAABB, g, true);
				}

				{//Floor
					//Shape
					var wallSd:b2BoxDef = new b2BoxDef();
					{
						wallSd.extents.Set(FLOOR_W/2 / m_physScale, FLOOR_H/2 / m_physScale);
//						wallSd.localRotation = Math.random() * Math.PI / 8;
						wallSd.restitution = 0.9;
					}
					//Body
					var wallBd:b2BodyDef = new b2BodyDef();
					{
						wallBd.position.Set(FLOOR_W/2 / m_physScale, (FLOOR_Y + FLOOR_H/2) / m_physScale);
						wallBd.AddShape(wallSd);
					}
					//Create
					m_world.CreateBody(wallBd);
				}

				{//Player
					//collision
					{
						//Shape
						var playerSd:b2CircleDef = new b2CircleDef();
						{
							playerSd.radius = PLAYER_R / m_physScale;
	//						playerSd.localRotation = Math.random() * Math.PI / 8;
							playerSd.density = 2;
							playerSd.friction = 0.0;
	//						playerSd.restitution = 0.0;
						}
						//Body
						var playerBd:b2BodyDef = new b2BodyDef();
						{
							playerBd.AddShape(playerSd);
						}
						//Create
						playerBd.position.Set(PLAYER_X / m_physScale, PLAYER_Y / m_physScale);
						m_Player = m_world.CreateBody(playerBd);
					}

					//graphic
					{
						m_PlayerGraphic = new Sprite();
						stage.addChild(m_PlayerGraphic);

						//in_textを表示するBitmapを作成する
						var createAA:Function = function(in_text:String):Bitmap{
							var text_field:TextField = new TextField();

							text_field.text = in_text;

							text_field.border = false;
							text_field.x = 0;
							text_field.y = 0;
							text_field.width = 100;
							text_field.height = 100;

	//						m_PlayerGraphic.addChild(text_field);

							var bmp_data : BitmapData = new BitmapData( 100 , 100 , true , 0x00000000);

							var matrix : Matrix = new Matrix(1,0,0,1,0,0);
							var color : ColorTransform = new ColorTransform(1,1,1,1,0,0,0,0);
							var rect : Rectangle = new Rectangle(0,0,400,300);
							bmp_data.draw(text_field, matrix, color, BlendMode.NORMAL, rect, true);

							var bmp_obj:Bitmap = new Bitmap( bmp_data , PixelSnapping.AUTO , true);
							bmp_obj.x = -text_field.textWidth*0.5;
							bmp_obj.y = -text_field.textHeight*0.5;

							return bmp_obj;
						};

						//今のところ、生のstringで渡している(ファイルから読み込ませたいところ)
						var bmp_obj:Bitmap = createAA("┏(^o^)┛\n     ┛┓");

						m_PlayerGraphic.addChild(bmp_obj);
					}
				}

				{//Bullet Init
					//Shape
					var ballSd:b2CircleDef = new b2CircleDef();
					{
						ballSd.radius = BULLET_R / m_physScale;
//						ballSd.localRotation = Math.random() * Math.PI / 8;
						ballSd.density = 2;
						ballSd.friction = 0.2;
						ballSd.restitution = 0.9;
					}
					//Body
					m_BulletBd = new b2BodyDef();
					{
						m_BulletBd.AddShape(ballSd);
					}
					//Create
//					for(var t:int = 0; t < 1; ++t){
//						ballBd.position.Set((300 + t*0.1) / m_physScale / 2, (100 - t*20) / m_physScale);
//						m_world.CreateBody(ballBd);
//					}
				}

				{//Blocks Init
					var sd:b2BoxDef = new b2BoxDef();
					sd.density = 1;
					sd.friction = 0.2;
					sd.extents.Set(BLOCK_W/2 / m_physScale, BLOCK_H/2 / m_physScale);
					var bd:b2BodyDef = new b2BodyDef();
					bd.AddShape(sd);
					for (var i:int = 0; i < 10; i++) {
						bd.position.Set(BLOCK_X / m_physScale, (FLOOR_Y - BLOCK_H/2 - i*BLOCK_H) / m_physScale);
						m_world.CreateBody(bd);
					}
				}
			}

			addEventListener("enterFrame", function(event:Event):void {
				Update();
			});
		}

		//=Input=
		private function onKeyDown(event:KeyboardEvent):void{
			if(event.keyCode == Keyboard.LEFT){
				m_InputL = 1;
			}
			if(event.keyCode == Keyboard.RIGHT){
				m_InputR = 1;
			}
			if(event.keyCode == Keyboard.UP){
				m_InputU = 1;
			}
			if(event.keyCode == Keyboard.DOWN){
				m_InputD = 1;
			}
			if(event.keyCode == Keyboard.SPACE){
				m_InputSpace = 1;
			}
			if(event.keyCode == KEY_S){
				//ここで生成してしまう
				shot();
			}
		}
		private function onKeyUp(event:KeyboardEvent):void{
			if(event.keyCode == Keyboard.LEFT){
				m_InputL = 0;
			}
			if(event.keyCode == Keyboard.RIGHT){
				m_InputR = 0;
			}
			if(event.keyCode == Keyboard.UP){
				m_InputU = 0;
			}
			if(event.keyCode == Keyboard.DOWN){
				m_InputD = 0;
			}
			if(event.keyCode == Keyboard.SPACE){
				m_InputSpace = 0;
			}
		}


		//=Shot=

		//弾の生成
		private function shot():void{
			m_BulletBd.position.Set(BULLET_X / m_physScale, BULLET_Y / m_physScale);
			m_BulletBd.linearVelocity.Set(BULLET_V / m_physScale, 0);
			m_Bullet.push(m_world.CreateBody(m_BulletBd));
		}


		//=Update=

		public function Update():void {
			if(!m_world) {
				return;
			}

			{//player update
				m_Player.m_linearVelocity.x = PLAYER_V * (m_InputR - m_InputL);
				if(m_InputU > 0){
					m_Player.m_linearVelocity.y = -PLAYER_V;
				}

				m_PlayerGraphic.x = m_Player.m_position.x * m_physScale;
				m_PlayerGraphic.y = m_Player.m_position.y * m_physScale;
			}

			{//bullet update
				m_Bullet.forEach(
					function(bullet:b2Body, index:int, arr:Array):void{
						bullet.m_force.Add(b2Math.MulFV(bullet.GetMass(), new b2Vec2(0.0, -GRAVITY)));
					}
				);
			}

			//Box2D Update
			m_world.Step(1 / 30, 10);

			// Render
			graphics.clear();
			for (var bb:b2Body = m_world.m_bodyList; bb; bb = bb.m_next) {
				for (var s:b2Shape = bb.GetShapeList(); s != null; s = s.GetNext()) {
					DrawShape(s);
				}
			}
		}


		//=Render=

		public function DrawShape(shape:b2Shape):void {
			//box
			if(shape.m_type == b2Shape.e_polyShape) {
				var drawBox:Function = function():void{
					var poly:b2PolyShape = shape as b2PolyShape;
					var tV:b2Vec2 = b2Math.AddVV(poly.m_position, b2Math.b2MulMV(poly.m_R, poly.m_vertices[i]));

					graphics.beginFill(0x999999, 1);
					graphics.lineStyle(1,0xffffff,1);
					graphics.moveTo(tV.x * m_physScale, tV.y * m_physScale);

					for (var i:int = 0; i < poly.m_vertexCount; ++i) {
						var v:b2Vec2 = b2Math.AddVV(poly.m_position, b2Math.b2MulMV(poly.m_R, poly.m_vertices[i]));
						graphics.lineTo(v.x * m_physScale, v.y * m_physScale);
					}
					graphics.lineTo(tV.x * m_physScale, tV.y * m_physScale);

					graphics.endFill();
				};

				drawBox();
			}
/*
			//circle
			if(shape.m_type == b2Shape.e_circleShape) {
				var drawCircle:Function = function():void{
					var circle:b2CircleShape = shape as b2CircleShape;
					var pos:b2Vec2 = circle.m_position;
					var r:Number = circle.m_radius;

					graphics.beginFill(0x999999, 1);
					graphics.lineStyle(1,0xaaaaaa,1);

					graphics.drawCircle(pos.x * m_physScale, pos.y * m_physScale, r * m_physScale);

					graphics.endFill();
				};

				drawCircle();
			}
//*/
		}
	}
}