Box2D関連のログ

状況

重力を相殺しつつ進む球を作成した。sキーで球を発射し、積み木にぶつける。

重力相殺は、Step実行前に毎回「逆方向の力×質量」を加えることで行う。
力を加えて相殺してる（速度の外部セットではない）ので、物体に当たってからの跳ね返りは物理エンジンの計算任せで行える。たぶん、接触したら消すようにするから意味ないんだけど。どっかで使う機会もあるかもしれない。

google page creatorにswfを上げればここに埋め込めるのではないか、と思い立つもアカウント名を忘れた。一度家に帰らねばわからん。

コード

package {
	import Box2D.Dynamics.*;
	import Box2D.Collision.*;
	import Box2D.Collision.Shapes.*;
	import Box2D.Common.Math.*;
	import flash.events.Event;
	import flash.display.*;
	import flash.text.TextField;
	//Input
	import flash.ui.Keyboard;
	import flash.events.KeyboardEvent;

	[SWF(backgroundColor="#ffffff", width="350", height="200")]
	public class Main extends Sprite {
		private var m_world:b2World;
		private var m_physScale:Number = 10;

		static public const GRAVITY:Number = 10.0;

		//弾
		private var m_BulletBd:b2BodyDef;
		private var m_Bullet:Array = new Array;

		//Input
		private var m_InputL:int = 0;
		private var m_InputR:int = 0;
		private var m_InputU:int = 0;
		private var m_InputD:int = 0;
		private var m_InputSpace:int = 0;

		static public const KEY_S:int = 83;


		public function Main() {
			stage.scaleMode = "noScale";
			stage.align = "TL";

			{//Init Input
				stage.addEventListener(KeyboardEvent.KEY_DOWN, onKeyDown);
				stage.addEventListener(KeyboardEvent.KEY_UP, onKeyUp);
			}

			{//Init Box2D
				{//Common
					//AABB
					var worldAABB:b2AABB = new b2AABB();
					worldAABB.minVertex.Set(-100.0, -100.0);
					worldAABB.maxVertex.Set(100.0, 100.0);
					//Gravity
					var g:b2Vec2 = new b2Vec2(0.0, GRAVITY);
					//World
					m_world = new b2World(worldAABB, g, true);
				}

				{//Floor
					//Shape
					var wallSd:b2BoxDef = new b2BoxDef();
					{
						wallSd.extents.Set(300 / m_physScale / 2, 10 / m_physScale);
//						wallSd.localRotation = Math.random() * Math.PI / 8;
						wallSd.restitution = 0.9;
					}
					//Body
					var wallBd:b2BodyDef = new b2BodyDef();
					{
						wallBd.position.Set(300 / m_physScale / 2, 250 / m_physScale);
						wallBd.AddShape(wallSd);
					}
					//Create
					m_world.CreateBody(wallBd);
				}

				{//Bullet Init
					//Shape
					var ballSd:b2CircleDef = new b2CircleDef();
					{
						ballSd.radius = 10 / m_physScale;
//						ballSd.localRotation = Math.random() * Math.PI / 8;
						ballSd.density = 4;
						ballSd.friction = 0.2;
						ballSd.restitution = 0.9;
					}
					//Body
					m_BulletBd = new b2BodyDef();
					{
						m_BulletBd.AddShape(ballSd);
					}
					//Create
//					for(var t:int = 0; t < 1; ++t){
//						ballBd.position.Set((300 + t*0.1) / m_physScale / 2, (100 - t*20) / m_physScale);
//						m_world.CreateBody(ballBd);
//					}
				}

				// Add bodies
	            var sd:b2BoxDef = new b2BoxDef();
	            sd.density = 1;
	            sd.friction = 0.2;
	            var bd:b2BodyDef = new b2BodyDef();
	            bd.AddShape(sd);
	            for (var i:int = 0; i < 10; i++) {
	                sd.extents.Set(30 / m_physScale, 10 / m_physScale);
	                bd.position.Set(200 / m_physScale, (160 - i * 20) / m_physScale);
	                m_world.CreateBody(bd);
	            }
			}

			addEventListener("enterFrame", function(event:Event):void {
				Update();
			});
		}

		//=Input=
		private function onKeyDown(event:KeyboardEvent):void{
			if(event.keyCode == Keyboard.LEFT){
				m_InputL = 1;
			}
			if(event.keyCode == Keyboard.RIGHT){
				m_InputR = 1;
			}
			if(event.keyCode == Keyboard.UP){
				m_InputU = 1;
			}
			if(event.keyCode == Keyboard.DOWN){
				m_InputD = 1;
			}
			if(event.keyCode == Keyboard.SPACE){
				m_InputSpace = 1;
			}
			if(event.keyCode == KEY_S){
				//ここで生成してしまう
				shot();
			}
		}
		private function onKeyUp(event:KeyboardEvent):void{
			if(event.keyCode == Keyboard.LEFT){
				m_InputL = 0;
			}
			if(event.keyCode == Keyboard.RIGHT){
				m_InputR = 0;
			}
			if(event.keyCode == Keyboard.UP){
				m_InputU = 0;
			}
			if(event.keyCode == Keyboard.DOWN){
				m_InputD = 0;
			}
			if(event.keyCode == Keyboard.SPACE){
				m_InputSpace = 0;
			}
		}


		//=Shot=

		//弾の生成
		private function shot():void{
			m_BulletBd.position.Set(50 / m_physScale / 2, 200 / m_physScale);
			m_BulletBd.linearVelocity.Set(100 / m_physScale, 0);
			m_Bullet.push(m_world.CreateBody(m_BulletBd));
		}


		//=Update=

		public function Update():void {
			if(!m_world) {
				return;
			}

			{//bullet update
				m_Bullet.forEach(
					function(bullet:b2Body, index:int, arr:Array):void{
						bullet.m_force.Add(b2Math.MulFV(bullet.GetMass(), new b2Vec2(0.0, -GRAVITY)));
					}
				);
			}

			//Box2D Update
			m_world.Step(1 / 30, 10);

			// Render
			graphics.clear();
			for (var bb:b2Body = m_world.m_bodyList; bb; bb = bb.m_next) {
				for (var s:b2Shape = bb.GetShapeList(); s != null; s = s.GetNext()) {
					DrawShape(s);
				}
			}
		}


		//=Render=

		public function DrawShape(shape:b2Shape):void {
			//box
			if(shape.m_type == b2Shape.e_polyShape) {
				var drawBox:Function = function():void{
					var poly:b2PolyShape = shape as b2PolyShape;
					var tV:b2Vec2 = b2Math.AddVV(poly.m_position, b2Math.b2MulMV(poly.m_R, poly.m_vertices[i]));

					graphics.beginFill(0x999999, 1);
					graphics.lineStyle(1,0xffffff,1);
					graphics.moveTo(tV.x * m_physScale, tV.y * m_physScale);

					for (var i:int = 0; i < poly.m_vertexCount; ++i) {
						var v:b2Vec2 = b2Math.AddVV(poly.m_position, b2Math.b2MulMV(poly.m_R, poly.m_vertices[i]));
						graphics.lineTo(v.x * m_physScale, v.y * m_physScale);
					}
					graphics.lineTo(tV.x * m_physScale, tV.y * m_physScale);

					graphics.endFill();
				};

				drawBox();
			}

			//circle
			if(shape.m_type == b2Shape.e_circleShape) {
				var drawCircle:Function = function():void{
					var circle:b2CircleShape = shape as b2CircleShape;
					var pos:b2Vec2 = circle.m_position;
					var r:Number = circle.m_radius;

					graphics.beginFill(0x999999, 1);
					graphics.lineStyle(1,0xaaaaaa,1);

					graphics.drawCircle(pos.x * m_physScale, pos.y * m_physScale, r * m_physScale);

					graphics.endFill();
				};

				drawCircle();
			}

		}
	}
}